2023-07-24

ぷちコンでやることを決める

日記

7/24　ZETAが勝って嬉しい。テストも100点でした。

第20回UE5ぷちコンが始まりました

UE5ぷちコンは、ヒストリアさん主催のUE限定ゲームコンテストです。（私は過去に２回受賞しています！）

今回のテーマは「コントロール」ということで、深いですね～。

なので私はコントローラを自作しようと思います。接続を処理するのはUE側なので問題ないかな！

自作するコントローラ

すごい設計図を書きました。コントローラにはI2C通信のセンサを２つまで付けることができ、付け替えてステージを攻略していきます。

接続方法としてはBLEにするつもりです。せっかくプラグインも買ってあるので、主な制御をUEで行えばコンテストの趣旨に合うはず...。

ですが問題もあり、BLE Utility V2プラグインはiOS, Androidでしか動作しません。プログラムテストもやりにくいので、テスト用アプリなど作って頑張ります。

一応、WinRTなど使ってPCでBLE通信を行うこともできるのですが、そんな実力も時間もないです。

付け替えモジュール

センサの値を読み取るのは普通にやればいいですが、LEDモジュールを追加して、ゲームの画面以外にも情報を出力したい気持ちがあります。そのため、ゲーム側からキャラクタリスティックに値を送信してLEDの色を変えてみたいと思います。

用意するものはBlinkM(LED), Arduino Nano 33 BLEです。BlinkMはI2Cで色を変えることができるLEDです。研究室に転がっていました。

Arduinoのプログラムは以下のようになります。

#include <ArduinoBLE.h>
#include <Wire.h>

#define BLINKM_ADDRESS 0x09

BLEService rgbService("19B10000-E8F2-537E-4F6C-D104768A1214"); // BLE RGB Service

// RGB characteristics
BLEUnsignedCharCharacteristic redCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);
BLEUnsignedCharCharacteristic greenCharacteristic("19B10002-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);
BLEUnsignedCharCharacteristic blueCharacteristic("19B10003-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);

void setup() {
  Serial.begin(9600);
  while (!Serial);

  Wire.begin();

  if (!BLE.begin()) {
    Serial.println("starting BLE failed!");
    while (1);
  }

  BLE.setLocalName("RGB Controller");
  BLE.setAdvertisedService(rgbService);

  rgbService.addCharacteristic(redCharacteristic);
  rgbService.addCharacteristic(greenCharacteristic);
  rgbService.addCharacteristic(blueCharacteristic);

  BLE.addService(rgbService);

  redCharacteristic.setValue(0);
  greenCharacteristic.setValue(0);
  blueCharacteristic.setValue(0);

  BLE.advertise();

  Serial.println("Bluetooth device active, waiting for connections...");
}

void loop() {
  BLEDevice central = BLE.central();

  if (central) {
    Serial.print("Connected to central: ");
    Serial.println(central.address());
    while (central.connected()) {
      if (redCharacteristic.written() || greenCharacteristic.written() || blueCharacteristic.written()) {
        setBlinkMColor(redCharacteristic.value(), greenCharacteristic.value(), blueCharacteristic.value());
      }
    }
    Serial.print("Disconnected from central: ");
    Serial.println(central.address());
  }
}

void setBlinkMColor(uint8_t red, uint8_t green, uint8_t blue) {
  Wire.beginTransmission(BLINKM_ADDRESS);
  Wire.write('n');
  Wire.write(red);
  Wire.write(green);
  Wire.write(blue);
  Wire.endTransmission();
}

プログラムの折りたたみ方を知らないのでこのまま貼ってます。キャラクタリスティックを3つ用意して、16進数でRGBそれぞれの値を送ると反映されます。

動かしてみる

nRF Connectでテストします。

キャラクタリスティックを、赤0xFF, 緑0x00, 青0xFFとすることでRGB(255, 0, 255)となり、マゼンタに光るのがわかります。全部0x00にするとLEDが消えます。

付け替えする規格

大体のセンサではI2Cが採用されているので、電源供給±とSDA, SCLピンの計4ピンでいいと思います。これをポゴピンで簡単に着脱できるようにすればOKかな。

夏休み中は実家と研究室が遠いので3Dプリンターが使えなくなります。運転すれば行ける距離ではあるので、事故らないようにたまに行こうと思います。

2023-07-20

BLEで複数の文字列を扱う

日記

7/20 Viewfinder面白かった

3Dプリンターでカプセルを造形

お手玉のガワを作るため、

ただのカプセルにFusionでねじを付けたやつを印刷します。そのまま印刷しても入らないのでナット側を0.3mm凹ませました。参考
完成品はこちら。

ちょっと隙間があるのは、時間短縮のためにサポート材無しで印刷したらぐちゃぐちゃになってしまったからです。ねじ山の方はサポート材あったほうがいいかも。

BLEでスティックとボタンの値を送信

プログラムはこんな感じ。サービスUUIDはハートレートプロファイルを使っているので、nRF Connectではハートマークが表示されます。

#include <ArduinoBLE.h>

BLEService myService("180D");  // BLE Heart Rate Service

// BLE Characteristics
BLEStringCharacteristic stickCharacteristic("2A37", BLERead | BLENotify, 20); // max length 20 bytes
BLEIntCharacteristic switchCharacteristic("2A38", BLERead | BLENotify);

const int stickXPin = A0;
const int stickYPin = A1;
const int stickPushPin = 2;
const int switchPin = 3;

void setup() {
  Serial.begin(9600);
  while (!Serial);

  pinMode(stickXPin, INPUT);
  pinMode(stickYPin, INPUT);
  pinMode(stickPushPin, INPUT);
  pinMode(switchPin, INPUT);

  if (!BLE.begin()) {
    Serial.println("starting BLE failed!");
    while (1);
  }

  BLE.setLocalName("MyDevice");
  BLE.setAdvertisedService(myService);

  myService.addCharacteristic(stickCharacteristic);
  myService.addCharacteristic(switchCharacteristic);

  BLE.addService(myService);

  BLE.advertise();

  Serial.println("Bluetooth device active, waiting for connections...");
}

void loop() {
  BLEDevice central = BLE.central();

  if (central) {
    Serial.print("Connected to central: ");
    Serial.println(central.address());
    while (central.connected()) {
      int stickX = analogRead(stickXPin);
      int stickY = analogRead(stickYPin);
      int stickPush = digitalRead(stickPushPin);
      int switchState = digitalRead(switchPin);

      String stickData = String(stickX) + "," + String(stickY) + "," + String(stickPush);
      stickCharacteristic.writeValue(stickData);
      switchCharacteristic.writeValue(switchState);

      // Print the data to the Serial Monitor
      Serial.print("Stick Data: " + stickData);
      Serial.println("Switch State: " + String(switchState));
    }
    Serial.print("Disconnected from central: ");
    Serial.println(central.address());
  }
}

で、BLE Utilitiesプラグインを使って作ったアプリで接続してみると...

こんな感じで、Dataがすべて数字になっています。Arduinoのプログラムでは文字列で送信しているので、アプリ側に問題があります。

UE C++でバイト配列を文字列に変換する

残念ながらブループリントではできないっぽいので、UE C++を扱うためにVisual Studioを入れるとこから始めます。

UE4.27はVisual Studio 2019です。プログラムは以下のような感じになります。

//cpp
FString UYourClass::BytesToString(const TArray<uint8>& InArray)
{
    FString Result;
    for (auto InChar : InArray)
    {
        Result += FString::Printf(TEXT("%c"), InChar);
    }
    return Result;
}

// .h
#pragma once

#include "CoreMinimal.h"
#include "YourClass.generated.h"

UCLASS()
class YOURPROJECT_API UYourClass : public UObject
{
    GENERATED_BODY()

public:
    UFUNCTION(BlueprintCallable, Category = "Your Category")
    static FString BytesToString(const TArray<uint8>& InArray);
};